#### Form

The Form collection retrieves the values of form elements posted to the HTTP request body, with a form using the POST method.

###### Syntax

Request.Form(element)[(index)|.Count]

###### Parameters

element
  The name of the form element from which the collection is to retrieve values.
index
  An optional parameter that enables you to access one of multiple values for a parameter. It can be any integer in the range 1 to Request.Form(parameter).Count.

###### Remarks

The Form collection is indexed by the names of the parameters in the request body. The value of Request.Form(element) is an array of all the values of element that occur in the request body. You can determine the number of values of a parameter by calling Request.Form(element).Count. If a parameter does not have multiple values associated with it, the count is 1. If the parameter is not found, the count is 0.

To reference a single value of a form element that has multiple values, you must specify a value for index. The index parameter may be any number between 1 and Request.Form(element).Count. If you reference one of multiple form parameters without specifying a value for index, the data is returned as a comma-delimited string.

When you use parameters with Request.Form, the Web server parses the HTTP request body and returns the specified data. If your application requires unparsed data from the form, you can access it by calling Request.Form without any parameters.

Note When using ASP and posting large amounts of data beyond 100 kilobytes, Request.Form cannot be used. If your application requires posting data greater than this limit, a component can be written which uses the Request.BinaryRead method.

You can iterate through all the data values in a form request. For example, if a user filled out a form by specifying two values - Chocolate and Butterscotch - for the FavoriteFlavor element, you could retrieve those values by using the following script.

    <%
      For i = 1 To Request.Form("FavoriteFlavor").Count
        Response.Write Request.Form("FavoriteFlavor")(i) & "<BR>"
      Next
    %>

The preceding script would display the following.

    Chocolate
    Butterscotch

You can use this technique to display the parameter name, as shown in the following script:

    <%
      For i = 1 to Request.Form("FavoriteFlavor").count %>
        Request.Form(FavoriteFlavor) = <%= Request.Form("FavoriteFlavor")(i)_
        %> <BR>
    <% Next %>

This script displays the following in the browser.

    Request.Form(FavoriteFlavor) = Chocolate
    Request.Form(FavoriteFlavor) = Butterscotch

###### Example

Consider the following form:

    <FORM ACTION = "/scripts/submit.asp" METHOD = "post">
    <P>Your first name: <INPUT NAME = "firstname" SIZE = 48>
    <P>What is your favorite ice cream flavor: <SELECT NAME = "flavor">
    <OPTION>Vanilla
    <OPTION>Strawberry
    <OPTION>Chocolate
    <OPTION>Rocky Road</SELECT>
    <P><INPUT TYPE = SUBMIT>
    </FORM>

From that form, the following request body might be sent:

    firstname=James&flavor=Rocky+Road

The following script can then be used:

    Welcome,  <%= Request.Form("firstname") %>.
    Your favorite flavor is <%= Request.Form("flavor") %>.

The following output is the result:

    Welcome, James. Your favorite flavor is Rocky Road.

If the following script is used:

    The unparsed form data is:  <%= Request.Form %>

the output would be:

    The unparsed form data is:  firstname=James&flavor=Rocky+Road

Note If your form includes multiple objects with the same name (for example, HTML SELECT tags), the item in the form collection will be a comma-delimited list of all the selected values.

###### Applies To

Request Object

###### See Also

ClientCertificate, Cookies, QueryString, ServerVariables

© 1997-2001 Microsoft Corporation. All rights reserved.